Navigation:  Klassen > bBrowser >

bBrowser:EnableCaptionSortMarker()

Diese Seite drucken    Vorherige SeiteZurück zum Anfang des KapitelsNächste Seite

Zweck

Schaltet die Anzeige von Sortiermarkierungen in den Spaltenbezeichnungen ein bzw. aus.

Klasse

bBrowser

Typ

Methode

Syntax

<oBrowser>:EnableCaptionSortMarker([<lEnable>]) Æ NIL

Argumente

<lEnable>Logischer Wert, der definiert, ob Sortiermarkierungen in den Spaltenbezeichnungen angezeigt werden können. Als Vorgabewert wird TRUE verwendet.
Datentyp:Logic

Beschreibung

bBrowser:EnableCaptionSortMarker() schaltet das Anzeigen von Sortiermarkierungen in den Spaltenbezeichnungen ein bzw. aus. Die Sortiermarkierung für eine Spalte kann mit dem Zugriff bBrowserColumn:CaptionSortMarker definiert werden.

 

CaptionSortMarker

 

Die Sortiermarkierungen werden am oberen Rand innerhalb der Spaltenbezeichnung angezeigt. Damit am oberen Rand genügend Platz für die Sortiermarkierung ist, kann entweder mit dem Zugriff bBrowser:AutoCaptionHeight die automatische Berechnung der Höhe der Spaltenbezeichnungen im bBrowser eingeschaltet werden oder es muss mit dem Zugriff bBrowser:CaptionHeight die Höhe der gesamten Spaltenbezeichnungen angepasst werden und zusätzlich mit dem Zugriff bBrowser:CaptionView:Grid:InnerSpace die Höhe des Bereichs zwischen dem oberen Rand der Spaltenbezeichnungen und deren Inhalt angepasst werden. Um wie viel Pixel die Höhe angepasst werden muss, kann mit der Methode bBrowser:PropertyGet() und der Property #SortMarkerHeight ermittelt werden.

 

Anmerkungen

Mit der Methode bBrowser:IsCaptionSortMarker() kann zu einem späteren Zeitpunkt geprüft werden, ob Sortiermarkierungen angezeigt werden.

 

Die Anzeige von Sortiermarkierungen ist nach dem Erzeugen des bBrowser ausgeschaltet.

Beispiele

In dem folgenden Beispiel wird ein bBrowser erzeugt, die Sortiermarkierungen eingeschaltet und für die Spalte zum Feld LASTNAME die Sortiermarkierung gesetzt. Die Höhe der Spaltenbezeichnungen wird automatisch mit dem Zugriff bBrowser:AutoCaptionHeight angepasst.

 

LOCAL odbsCUSTOMER AS DBServer
LOCAL oBrowser     AS bBrowser
LOCAL oColumn      AS bDataColumn
 
// Browser erzeugen
odbsCUSTOMER := DBServer{"CUSTOMER"}
odbsCUSTOMER:SetOrder("NAME")
 
oBrowser := bBrowser{oOwner,;
                     1000,;
                     Point{0, 0},;
                     Dimension{300, 250}}
 
// Sortiermarkierungen im Browser aktivieren
oBrowser:AutoCaptionHeight := TRUE
oBrowser:EnableCaptionSortMarker(TRUE)
 
// Server im Browser setzen und Browser anzeigen
oBrowser:Use(odbsCUSTOMER)
oBrowser:Show()

 
// Sortiermarkierung in Spalte LASTNAME setzen
oColumn := oBrowser:GetColumn(#LASTNAME)
oColumn:CaptionSortMarker := BDCF_SORTMARKER_UP
 
// Wichtig!!!
// -> Browser zeichnen
oBrowser:Redraw(#CAPTION)

 

In dem folgenden Beispiel wird ein bBrowser erzeugt, die Sortiermarkierungen eingeschaltet und für die Spalte zum Feld LASTNAME die Sortiermarkierung gesetzt. Die Höhe der Spaltenbezeichnungen wird manuell angepasst.

 

LOCAL odbsCUSTOMER AS DBServer
LOCAL oBrowser     AS bBrowser
LOCAL oColumn      AS bDataColumn
 
// Browser erzeugen
odbsCUSTOMER := DBServer{"CUSTOMER"}
odbsCUSTOMER:SetOrder("NAME")
 
oBrowser := bBrowser{oOwner,;
                     1000,;
                     Point{0, 0},;
                     Dimension{300, 250}}
 
// Sortiermarkierungen im Browser aktivieren
oBrowser:EnableCaptionSortMarker(TRUE)

oBrowser:CaptionView:Grid:SpaceTop := oBrowser:PropertyGet(#SortMarkerHeight)
oBrowser:CaptionHeight += oBrowser:PropertyGet(#SortMarkerHeight)
oBrowser:Recalculate()

 
// Server im Browser setzen und Browser anzeigen
oBrowser:Use(odbsCUSTOMER)
oBrowser:Show()

 
// Sortiermarkierung in Spalte LASTNAME setzen
oColumn := oBrowser:GetColumn(#LASTNAME)
oColumn:CaptionSortMarker := BDCF_SORTMARKER_UP
 
// Wichtig!!!
// -> Browser zeichnen
oBrowser:Redraw(#CAPTION)

Siehe auch

bBrowser:AutoCaptionHeight

bBrowser:IsCaptionSortMarker()

bBrowser:PropertyGet()

bBrowserColumn:CaptionSortMarker

bGrid:InnerSpace

 


Page url: http://www.YOURSERVER.com/index.html?bbrowser_enablecaptionsortmarker.htm